Sonuçlar 1 to 2 of 2

Konu: ActiveX Kontrol ( OCX ) Oluşturmak(kaynak1.v.basic)

  1. #1

    Default ActiveX Kontrol ( OCX ) Oluşturmak(kaynak1.v.basic)

    ActiveX Kontrol ( OCX ) Oluşturmak



    AccessKeys : Kısayol tuşu

    Alignable : True - Align özelliği var

    Ambient : Kontrolun bulunacağı yerin özellikleri

    CanGetFocus : True – Tab tuşu ile kontrole erişilebilir

    ControlContainer : True – İçerisine başka kontroller yerleştirilebilir

    DefaultCancel : Defaul ve Cancel özelliği

    EditAtDesignTime : True - Kontrolu tasarım zamanında çalıştırılabilme

    InvisibleAtRunTime : Kontrolün çalışma zamanında görünmesi

    PropertyPages : Özellikler penceresi

    Public : True - kontrol diğer uygulamalarda kullanabilir

    ToolBoxBitmap : Kontrolun ToolBox’a eklendiğinde görülecek olan resim



    Initialize : Yeni bir kontrol üretilmesi

    InitProperties : Initialize olayı sonrası ilk değerlerin oluşumu

    Terminate : Kontrolün hafızadan silinmesi

    AccesKeyPress : AccessKeys ile belirlenen tuşa basılması

    Hide : Kontrolün gizlenmesi

    Show : Kontrolün gösterilmesi

    AmbientChanged : Ambient özelliklerinden birinin değişmesi

    EnterFocus : GotFocus

    ExitFocus : LostFocus

    ReadProperties : Propertiese aktarılan değerin okunması

    WriteProperties : Değerin properties’e aktarılması

    ReSize : Kontrolün boyutunun değişmesi

    Paint : Kontrol nesnesinin formda gözükmesi





    File > New Project > ActiveX Control





    Project > Project1 Proterties > General>

    Project > Type : ActiveX Control

    Project > Name : RTF Metin

    Project > Description : RTF Metin Editörü





    Make>

    Application > Title : RTFmetin

    ToolBox –RichTextBox – ImageList – StatusBar – CommonDialog - Image





    Private Sub UserControl_Paint()

    RichTextBox1.Width = UserControl.Width

    RichTextBox1.Height = UserControl.Height- Toolbar1.Height - StatusBar1.Height

    End Sub







    Private Sub Toolbar1_ButtonClick(ByVal Button As MSComctlLib.Button)

    Select Case Button.Index

    Case 1 ' Yeni

    RichTextBox1.Text = ""

    Case 2 ' Aç

    CommonDialog1.DialogTitle = "RTF Dosya Aç"

    CommonDialog1.Filter = "Rich Text Format|*.RTF|"

    CommonDialog1.FileName = ""

    CommonDialog1.ShowOpen

    RichTextBox1.LoadFile CommonDialog1.FileName

    StatusBar1.Panels(1).Text = CommonDialog1.FileName

    Case 3 ' Kaydet

    CommonDialog1.DialogTitle = "Kaydet"

    CommonDialog1.Filter = "Rich Text Format|*.RTF|"

    CommonDialog1.FileName = "adsız"

    CommonDialog1.ShowSave

    RichTextBox1.SaveFile CommonDialog1.FileName



    Case 5 ' Font özellikleri

    CommonDialog1.Flags = cdlCFScreenFonts

    CommonDialog1.DialogTitle = "Karakter Özellikleri"

    CommonDialog1.FontName = RichTextBox1.SelFontName

    CommonDialog1.FontBold = RichTextBox1.SelBold

    CommonDialog1.FontItalic = RichTextBox1.SelItalic

    CommonDialog1.FontSize = RichTextBox1.SelFontSize

    CommonDialog1.FontUnderline = RichTextBox1.SelUnderline

    CommonDialog1.FontStrikethru = RichTextBox1.SelStrikeThru

    CommonDialog1.ShowFont

    RichTextBox1.SelFontName = CommonDialog1.FontName

    RichTextBox1.SelBold = CommonDialog1.FontBold

    RichTextBox1.SelFontSize = CommonDialog1.FontSize

    RichTextBox1.SelItalic = CommonDialog1.FontItalic

    RichTextBox1.SelStrikeThru = CommonDialog1.FontStrikethru

    RichTextBox1.SelUnderline = CommonDialog1.FontUnderline

    Case 6 ' Font Rengi

    CommonDialog1.Flags = cdlCCRGBInit

    CommonDialog1.Color = RichTextBox1.SelColor

    CommonDialog1.ShowColor

    RichTextBox1.SelColor = CommonDialog1.Color

    Case 8 ' Resim Ekle

    CommonDialog1.DialogTitle = "Resim Ekle"

    CommonDialog1.Filter = "BitMap Picture|*.BMP|"

    CommonDialog1.FileName = ""

    CommonDialog1.ShowOpen

    Image1.Picture = LoadPicture(CommonDialog1.FileName)

    Clipboard.Clear

    Clipboard.SetData Image1.Picture

    RichTextBox1.SetFocus

    SendKeys "+{Insert}"



    Case 10 ' Yazdır

    CommonDialog1.DialogTitle = "Yazdır"

    CommonDialog1.Flags = cdlPDReturnDC + cdlPDNoPageNums

    If RichTextBox1.SelLength = 0 Then

    CommonDialog1.Flags = CommonDialog1.Flags + cdlPDAllPages

    Else

    CommonDialog1.Flags = CommonDialog1.Flags + cdlPDSelection

    End If

    CommonDialog1.Copies = 1

    CommonDialog1.ShowPrinter

    RichTextBox1.SelPrint CommonDialog1.hDC

    End Select

    End Sub

    Özellik Eklemek

    Public Property Get Metin() As String

    Metin = RichTextBox1.Text

    End Property



    Public Property Let Metin(ByVal vNewValue As String)

    RichTextBox1.Text = vNewValue

    End Property


    Programcının Özelliklerde Yaptığı Değişiklikleri Saklamak


    Private Sub UserControl_ReadProperties(PropBag As PropertyBag)

    Metin = PropBag.ReadProperty("metin")

    End Sub



    Private Sub UserControl_WriteProperties(PropBag As PropertyBag)

    PropBag.WriteProperty "metin", Metin

    End Sub


    Property Pages – Özellikler Sayfası Eklemek



    Project > Add Propety Page > Name : Metin





    Private Sub txtMetin_Change()
    Changed = True
    End Sub

    Private Sub PropertyPage_ApplyChanges()
    SelectedControls(0).Metin = txtMetin.Text
    End Sub

    Private Sub PropertyPage_SelectionChanged()
    txtMetin.Text = SelectedControls(0).Metin
    End Sub





    Olay Eklemek


    (General)(Declaration)



    Event dblclick()



    Private Sub StatusBar1_DblClick()

    RaiseEvent dblclick ‘ StatusBar çift tıklanınca kontrolün

    End Sub ‘ çift tıklama olayı oluşacak

  2. #2

Similar Threads

  1. Donanım (kaynak1.v.basic)
    By Elektronik in forum Visual Basic
    CEvaplar: 1
    Son Mesaj: 26-07-08, 10:15
  2. CEvaplar: 1
    Son Mesaj: 14-07-08, 19:51
  3. IFF-V.Basic-(kaynak1)
    By Elektronik in forum Visual Basic
    CEvaplar: 1
    Son Mesaj: 14-07-08, 19:46
  4. Choose-V.basic-(kaynak1)
    By Elektronik in forum Visual Basic
    CEvaplar: 1
    Son Mesaj: 14-07-08, 19:41
  5. SSTab – Tab Kontrol(kaynak1-v.basic)
    By Elektronik in forum Visual Basic
    CEvaplar: 0
    Son Mesaj: 04-11-07, 14:47

Tags for this Thread

Bookmarks

Gönderme izinleri

  • Yeni Konu açamazsınız
  • Konulara cevap yazamazsınız.
  • Eklenti gönderemezsiniz.
  • Mesajlarınızı düzenleme izniniz yok.
  •